Stephen Wright : ASP.NET

ASP.NET + StructureMap = Epic Win

Stephen Wright — Thu, 26 Nov 2009 04:51:03 GMT

After running into a lot of testing problems with my current architecture in ASP.NET, I decided that it was time to look into an IoC Framework. I have heard the marvels of how it makes code so much more isolated and clean (SOLID), but I couldn’t see my code ever getting to this point. Because this project has a ton of legacy code, there was little incentive to add anything else when it was already so highly coupled. I needed to take a step back and look at it from a different perspective.

I understood how IoC (Inversion of Control) Frameworks worked and knew how this technique is used, but I didn’t know how I could integrate it in my application. Most of my action/service methods were static classes that instantiated new objects to return what I needed.

Here’s an example:

On the member page, there is a list of upcoming conferences that calls this code:

Public Class ConferenceService    

	Public Shared Function GetUpcomingConferences(ByVal DisplayDate As DateTime) As IList(Of ConferenceEntity)        
		Using repo As New Repository            
			Dim bucket As New RelationPredicateBucket(ConferenceFields.IsActive = True)
            Dim startfilter As New PredicateExpression(ConferenceFields.StartDisplayDate = System.DBNull.Value)            
			startfilter.AddWithOr(ConferenceFields.StartDisplayDate <= DisplayDate)    
			bucket.PredicateExpression.AddWithAnd(startfilter)         

			Dim endfilter As New PredicateExpression(ConferenceFields.EndDisplayDate = System.DBNull.Value)   
			endfilter.AddWithOr(ConferenceFields.EndDisplayDate >= DisplayDate)           
			bucket.PredicateExpression.AddWithAnd(endfilter)          
			Dim sorter As New SortExpression(ConferenceFields.StartDateTimeUtc Or SortOperator.Ascending)    
			Return repo.GetCollection(Of ConferenceEntity)(bucket, sorter).ToList()    
		End Using   
	End Function
	
End Class

I am using LLBLGen (Adapter) as my DAL so the Repository class is responsible for calling a new object to create what LLBLGen calls an EntityCollection. This is easy to call because all I have to do is call ConferenceService.GetUpcomingConferences(Date.Now()) to get a list of upcoming conference. This is very hard to test though without using something like Typemock.

In order to start my refactoring to be able to integrate StructureMap, I needed to look at how my ConferenceService was being constructed. There are 5 constructor calls in this method alone. You can imagine how the rest of the application looks like.

Adding and Setting Up StructureMap

First, download StructureMap from the website. I downloaded version 2.5.3. Next was to look how to get StructureMap set up on the web project (found here http://structuremap.sourceforge.net/ConfiguringStructureMap.htm). I had to use for VB and lambdas are tricky so this is how the Bootstrapper was defined:

Imports StructureMap
Imports StructureMap.Configuration.DSL

Public Class Bootstrapper    
	
	Public Shared Sub BootstrapStructureMap()        
		ObjectFactory.Initialize(AddressOf ConfigStructureMap)    
	End Sub    

	Private Shared Sub ConfigStructureMap(ByVal x As IInitializationExpression)        
		x.AddRegistry(New RepositoryRegistry)    
	End Sub    
	
	Public Class RepositoryRegistry       
		Inherits Registry        
		
		Overrides Protected Sub configure()   
			'Will be used later after we refactor      
			'ForRequestedType(Of IRepository)().TheDefaultIsConcreteType(Of Repository)().CacheBy(Attributes.InstanceScope.Hybrid)   
		End Sub   
		
	 End Class
 End Class

And then, in our Global.asax, on the Application_Start, call the Bootstrapper.BootstrapStructureMap() method. That is all we need for StructureMap config for now. That will get us started in the right direction.

Refactoring

The first refactoring is to Extract an Interface from the Repository class. If you have a refactoring tool such as Refactor Pro! or Resharper, this is made very easy. I called mine, IRepository. This will make the Repository class implement the newly created interface. We can now start on the ConferenceService.

The next refactoring is to create a constructor for the ConferenceService class that takes an IRepository as a parameter. This will help us create Constructor Injection.

After we add the parameter, we can remove the code that uses the concrete Repository object.

 Public Class ConferenceService   
	 
	 Private _repo As IRepository    
	 ''' <summary>    
	 ''' Initializes a new instance of the ConferenceService class.    
	 ''' </summary>    
	 ''' <param name="repo"></param>    
	 Public Sub New(ByVal repo As IRepository)        
		_repo = repo    
	 End Sub    
	 
	 Public Function GetUpcomingConferences(ByVal DisplayDate As DateTime) As IList(Of ConferenceEntity)        
		 Dim bucket As New RelationPredicateBucket(ConferenceFields.IsActive = True)        
		 im startfilter As New PredicateExpression(ConferenceFields.StartDisplayDate = System.DBNull.Value)        
		 startfilter.AddWithOr(ConferenceFields.StartDisplayDate <= DisplayDate)        
		 bucket.PredicateExpression.AddWithAnd(startfilter)        
		 Dim endfilter As New PredicateExpression(ConferenceFields.EndDisplayDate = System.DBNull.Value)        
		 endfilter.AddWithOr(ConferenceFields.EndDisplayDate >= DisplayDate)        
		 bucket.PredicateExpression.AddWithAnd(endfilter)        
		 Dim sorter As New SortExpression(ConferenceFields.StartDateTimeUtc Or SortOperator.Ascending)        
		 Return _repo.GetCollection(Of ConferenceEntity)(bucket, sorter).ToList()            
	End Function   
	
 End Class

The next piece of code is back in our Bootstrapper that we have to uncomment.

'ForRequestedType(Of IRepository)().TheDefaultIsConcreteType(Of Repository)().CacheBy(Attributes.InstanceScope.Hybrid)

Now, instead of calling the static method as such:

Dim upcomingConf as IList(Of ConferenceEntity) = ConferenceService.GetUpcomingConferences(Date.Now())

We can call it as such:

Dim upcomingConf as IList(Of ConferenceEntity) = new ConferenceService(ObjectFactory.GetInstance(Of IRepository)()).GetUpcomingConferences(Date.Now())

This allows us to decouple the concrete Repository object and allows for testing out our method. We’ll be able to write tests now to cover our legacy code, and allow for more flexible code.

Creating a Yellow Fade with ASP.NET AJAX Toolkit

Stephen Wright — Sun, 20 Jan 2008 17:28:37 GMT

I've always thought that the Yellow Fade Technique has been a great way to present changes to a web page. It's used in all of 37Signal's applications such as BaseCamp and CampFire. It highlights the changes in a page using a yellow background, then fades out to the normal background. This gives a visual cue to the user that something has changed on the page. You can also use it to get the user's attention (which is what I use it for).

I searched to find the JavaScript to use in my own application and couldn't find anything that was easily integrated into the "controls" structure of ASP.NET. Anything that I was going to use would need to hack into the body tag and the header tag to place functions initializing it. Here's a quick way to accomplish this using ASP.NET Ajax and the Control Toolkit.

This example assumes that you have .NET 3.5 and the AJAX Control Toolkit installed. If you don't have it, you can download the the .NET 3.5 Framework and the Control Toolkit from the official website: http://asp.net/ajax/

For this example, I am using the AnimationExtender. Here's the .aspx:

<ajaxToolkit:AnimationExtender ID="AnimationExtender1" runat="server" TargetControlID="divResponse" Enabled="True"/>

<div id="divResponse" runat="server" style="width: 500px; padding: 10px;    margin-bottom: 10px;" visible="false">

    <strong>

        <asp:Literal ID="litResponseText" runat="Server" />

    </strong>

</div>

Display Name: <asp:Textbox id="txtDisplay" runat="server"/>

<asp:LinkButton id="btnSubmit" runat="server" Text="Update"/>

The div named "divResponse" is the container for our response on postback. We can now add the code to handle adding the Animation properties to the AnimationExtender:

Protected Sub btnUpdate_Click(ByVal sender As Object, ByVal e As EventArgs) Handles btnUpdate.Click

        divResponse.Visible = True

        If String.IsNullOrEmpty(txtDisplayName.Text) Then

            litResponseText.Text = "Please enter a Display Name"

            AnimationExtender1.Animations = "<OnLoad><Sequence><Parallel Duration=""5""><Color Duration=""5"" StartValue=""#FF4500"" EndValue=""#FFFFFF"" Property=""style"" PropertyKey=""backgroundColor"" /><Color Duration=""4"" StartValue=""#000000"" EndValue=""#FF0000"" Property=""style"" PropertyKey=""color"" /></Parallel></Sequence></OnLoad>"

        Else

            'Save your Display Name property

            litResponseText.Text = "Updated Successfully"

            AnimationExtender1.Animations = "<OnLoad><Sequence><Parallel Duration=""5""><Color Duration=""5"" StartValue=""#FFD700"" EndValue=""#FFFFFF"" Property=""style"" PropertyKey=""backgroundColor"" /><Color Duration=""4"" StartValue=""#000000"" EndValue=""#008000"" Property=""style"" PropertyKey=""color"" /></Parallel></Sequence></OnLoad>"

        End If

    End Sub

The first thing we want to do is to make the divResponse visible. We then can start our processing. We want to add properties to the AnimationExtender based on if the properties were set properly. If it failed, we add the error text to the litResponseText Literal, then add Animation Property Tag, which would look like this in the end:

<ajaxToolkit:AnimationExtender ID="AnimationExtender1" runat="server"

        TargetControlID="divResponse" Enabled="True">

    <Animations>

        <OnLoad>

            <Sequence>

                <Parallel Duration="5">

                    <Color Duration="5" StartValue="#FF4500" EndValue="#FFFFFF"

                        Property="style" PropertyKey="backgroundColor=" />

                    <Color Duration="4" StartValue="#000000" EndValue="#FF0000"

                        Property="style" PropertyKey="color" />

                </Parallel>

            </Sequence>

        </OnLoad>

    </Animations>

</ajaxToolkit:AnimationExtender>

The Parallel tag will execute both of the properties at the same time. What we're doing is starting the div with a background of Red/Orange and fading this color to white, while the text color is fading from Black to Red.

If the Display Name was valid, we want to note a successful call. This will fade the background from yellow to white and the forecolor from black to green.

HTH

Time Zone Issues

Stephen Wright — Thu, 15 Nov 2007 08:37:39 GMT

Sounds like a book title, doesn't it? It's a horror story.

Currently, I'm using a class library that uses the Windows Registry to return information about a specific date. I found it on Code Project and it REQUIRED a full trust environment. Luckily, I didn't need to run in a shared hosting environment and I didn't want to build my own DST provider for every time zone. I've been using it for about 2 years now and I think it's time to move over to the new TimeZone2 functionality that will be included in the .NET Framework 3.5 release.

Kathy Kam, member of the BCL Team, says from a post a while ago:

In the “Orcas” September CTP, you’ll see that the BCL team has added a new class named “System.TimeZone2” that will allow you to:

Convert a DateTime from one time zone (not necessarily your machine’s time zone) to another
Get an object that describes your local time zone
Get an array of objects that describes all the available time zones on your machine
Serialize a time zone into a string
Create your own time zone object to represent any custom time zones

The best part about this is that… if you are on an Vista machine… all of those functionality will have Vista’s Dynamic Time Zone support, because our calculations are done with the time zone data available on your OS.

This is wonderful news for me. I no longer have to depend on the old class library to store my time zone information.

For more information on the TimeZoneInfo Class, you can read about it on the MSDN site.

IE6 VPC Image - Part Deux

Stephen Wright — Tue, 20 Mar 2007 20:46:00 GMT

Because the license to use the original IE6 VirtualPC image was good until April 1, 2007, Microsoft has released another version. You can download it directly from Microsoft here.

REF: IE Team Blog

My Favorite Little Function - FixUrl

Stephen Wright — Sat, 07 Oct 2006 05:45:00 GMT

One problem that I frequently run into is trying to get my javascript URLs to point to the correct directory by using the "~" root for an ASP.NET application. Here's a handy function that helps with trying to get to the root of a webapp:

Public Function FixUrl(ByVal Url As String) As String

Dim strReturn As String

If Url.StartsWith("~") And HttpContext.Current.Request.ApplicationPath <> "/" Then

strReturn = HttpContext.Current.Request.ApplicationPath & Url.Substring(1).Replace("//", "/")

ElseIf Url.StartsWith("~") Then

strReturn = Right(Url, Len(Url) - 1)

Else

strReturn = Url

End If

Return strReturn

End Function

So what this function will do is take any URL that is passed (such as "~/admin/user.aspx") will return the proper directory.

If you are running your application at this URL: http://mytestapp.domain.com/, it will return "/admin/user.aspx". If you are running it locally for testing, such as http://localhost/mytestapp/, it will return "/mytestapp/admin/user.aspx".

This helps out when you are adding URLs to javascript calls through code (such as window.open('/admin/user.aspx', null, 'etc...) and need to have a generic way to find the root of your application because the tilde will not work in this context.

Enjoy!